PROC SQL Tutorial (20 Examples)

This tutorial is designed for beginners who want to get started with PROC SQL. It also includes a detailed comparison of the functions used in SAS and PROC SQL.

Syntax of PROC SQL

The syntax of PROC SQL is as follows:

PROC SQL; SELECT column(s) FROM table(s) | view(s) WHERE expression GROUP BY column(s) HAVING expression ORDER BY column(s); QUIT; 

The SQL statements must be specified in the following order:

1. SELECT : Specify the columns (variables) to be selected.
2. FROM : Specify the table (dataset) to be queried.
3. WHERE : Filters the data based on a condition.
4. GROUP BY : Classifies data into groups based on the specified columns.
5. HAVING : Filters data with the GROUP BY clause.
6. ORDER BY : Sorts the rows (observations) by the specified columns.

Note : SELECT FROM clauses are required. All the other clauses are optional.

PROC SQL statement calls the SQL procedure and QUIT statement ends the procedure.

To memorize the order of SQL queries, you can use the mnemonic "SFWGHO".

We are going to look at the difference between SAS and PROC SQL.

You would hear the word 'schema' from SQL programmers. It refers to design of database. In other words, it is the framework of database.

In the SAS program below, we are creating sample data for illustration purposes by extracting a few observations from the dataset "BWEIGHT" stored in the SASHELP library.

data outdata ; set SASHELP.BWEIGHT (obs=1000); run;

PROC SQL STATEMENTS

proc sql; select * from outdata; Quit;

Asterisk (*) is used to select all columns (variables) in the order in which they are stored in the table. Outdata is the table (dataset) from which we need to select the columns.

To display the list of columns to the SAS log, use FEEDBACK option in the PROC SQL statement.

proc sql feedback; select * from outdata; Quit;

The SAS log is shown below:

71 proc sql feedback; 72 select * 73 from outdata; NOTE: Statement transforms to: select OUTDATA.Weight, OUTDATA.Black, OUTDATA.Married, OUTDATA.Boy, OUTDATA.MomAge, OUTDATA.MomSmoke, OUTDATA.CigsPerDay, OUTDATA.MomWtGain, OUTDATA.Visit, OUTDATA.MomEdLevel from outdata; 74 Quit;

In the SELECT clause, multiple columns are separated by commas.

proc sql; select weight,married from outdata; Quit;

In the SELECT clause, Weight and Married columns are specified so that we can select them from OUTDATA table.

Suppose you want to limit the number of rows that PROC SQL displays, use the OUTOBS= option in the PROC SQL statement.

proc sql outobs=50; select weight,married from outdata; Quit;

Suppose you want to rename a variable, use the column alias AS option in the PROC SQL statement.

options nolabel; proc sql; select weight,married as marriage from outdata; Quit;

The variable name has been renamed from married to marriage. options nolabel tells SAS not to use variable labels in SAS procedures. I used it so that you can see variable name has been changed to marriage.

Suppose you want to create a new variable that contains calculation.

proc sql; select weight, (weight*0.5) as newweight from outdata; Quit;

A new variable has been created and named newweight which is calculated on the basis of the existing variable weight.

The keyword CALCULATED is used to refer a previously calculated variable.

proc sql; select weight, (weight*0.5) as newweight, CALCULATED newweight*0.25 as revweight from outdata; Quit;

The keyword DISTINCT is used to eliminate duplicate rows from your query results.

In the following program, we are asking SAS to remove all those cases where in duplicates exist on combination of both the variables - weight and married.

proc sql; select DISTINCT weight, married from outdata; quit;

The DISTINCT * implies cases having same values in all the variables as a whole would be removed.

proc sql; select DISTINCT * from outdata; quit;

SAS-defined formats can be used to improve the appearance of the body of a report. You can also label the variables using LABEL keyword.

options label; proc sql; select weight FORMAT= 8.2 , married Label =" Married People" from outdata; Quit;

The ORDER BY clause returns the data in sorted order.

ASC option is used to sort the data in ascending order. It is the default option. DESC option is used to sort the data in descending order.

proc sql; select MoMAge, eight, married from outdata ORDER BY weight ASC, married DESC; Quit;

Use the WHERE clause with any valid SAS expression to subset data.

The BETWEEN-AND operator selects within an inclusive range of values.

Example : where salary between 4500 and 6000;

The CONTAINS or ? operator selects observations by searching for a specified set of characters within the values of a character variable.

Example : where firstname contains 'DE';
OR
where firstname ? 'DE';

The IN operator selects from a list of fixed values.

Example : where state = 'NC' or state = 'TX';

The easier way to write the above statement would be to use the IN operator.

where state IN ('NC','TX');

The IS MISSING or IS NULL operator selects missing values.

Example : where dateofbirth is missing

OR where dateofbirth is null

The LIKE Operator is used to select a pattern.

Important Point :

The WHERE clause can reference a previously calculated variable in two ways-

1. Use CALCULATED keyword.

2. Repeat the calculation in the WHERE clause.

PROC SQL; SELECT momage, (WEIGHT * .01) AS NEWWEIGHT FROM outdata WHERE CALCULATED NEWWEIGHT > 5; QUIT;

PROC SQL; SELECT momage, (WEIGHT * .01) AS NEWWEIGHT FROM outdata WHERE (WEIGHT * .01) > 5; QUIT;

The CASE WHEN statement is used in SQL to perform conditional logic and return different values based on specified conditions. The END statement is required when using the CASE WHEN statement.

PROC SQL; SELECT WEIGHT, CASE WHEN WEIGHT BETWEEN 0 AND 2000 THEN 'LOW' WHEN WEIGHT BETWEEN 2001 AND 3000 THEN 'MEDIUM' WHEN WEIGHT BETWEEN 3001 AND 4000 THEN 'HIGH' ELSE 'VERY HIGH' END AS NEWWEIGHT FROM outdata; QUIT;

The conditions within the CASE statement are as follows:

1. If the weight is between 0 and 2000 (inclusive), it is categorized as 'LOW'.
2. If the weight is between 2001 and 3000 (inclusive), it is categorized as 'MEDIUM'.
3. If the weight is between 3001 and 4000 (inclusive), it is categorized as 'HIGH'.
4. If the weight does not fall into any of the above ranges, it is categorized as 'VERY HIGH'.

The following operators can be used in CASE expression:

• All operators that IF uses (=, , NOT, NE, AND, OR, IN, etc)
• BETWEEN AND
• CONTAINS or '?' (wildcard operator)
• IS NULL or IS MISSING
• = *
• LIKE

Use GROUP BY clause to summarize or aggregate data. Summary functions are used on the SELECT statement to produce summary for each of the analysis variables.

proc sql; select momage, COUNT(married) AS marriage from outdata GROUP BY momage; Quit;

1. AVG/MEAN
2. COUNT/FREQ/N
3. SUM
4. MAX
5. MIN
6. NMISS
7. STD
8. VAR
9. T (t value)
10. USS (Uncorrelated Sum of Square)
11. CSS (Correlated Sum of Square)
12. RANGE

In order to subset data when grouping is in effect, the HAVING clause must be used.The variable specified in having clause must contain summary statistics.

proc sql; select momage, weight, COUNT(married) AS marriage from outdata GROUP BY momage, weight HAVING marriage > 2; Quit;

Important Point -

The WHERE clause cannot be used to subset aggregated data. To subset data with the GROUP BY clause you must use HAVING clause.

The CREATE TABLE statement can be used to create a new data set as output instead of a report produced in output window.

PROC SQL; CREATE TABLE table-name AS SELECT column(s) FROM table(s) | view(s) WHERE expression GROUP BY column(s) ORDER BY column(s); QUIT;

proc sql; create table health AS select weight, married from outdata ORDER BY weight ASC, married DESC; Quit;

Suppose you want to limit the number of rows that PROC SQL produces in the data set, use the INOBS= option in the PROC SQL statement.

proc sql INOBS=50; create table health AS select weight,married from outdata; Quit;

INOBS controls how many records are read from the dataset and OUTOBS controls how many records are written. Run the following program and see the difference. Both returns different results.

/* OUTOBS=Example*/ proc sql outobs=2; select age, count(*) as tot from sashelp.class group by age; quit; /* INOBS= Example */ proc sql inobs=4; select age, count(*) as tot from sashelp.class group by age; quit;

Suppose you are asked to calculate the unique number of age values by Sex columns using SASHELP.CLASS dataset.

You can use PROC SQL with COUNT(DISTINCT variable_name) to determine the number of unique values for a column.

PROC SQL; CREATE TABLE TEST1 as SELECT Sex, Count(distinct Age) AS Unique_count FROM sashelp.class GROUP BY Sex; QUIT;

You can use NMISS() function to compute the number of missing values in a variable. The COUNT() function returns the number of non-missing values in a variable.

data temp; input id; cards; 1 2 . 4 5 . ; run;

proc sql; select nmiss(id) as N_missings, count(id) as N, calculated N_missings + calculated N as total from temp; quit;

How to refer to a calculated variable

The keyword CALCULATED is used to refer to a newly created variable for further calculation. In this case, we have used CALCULATED to sum 'N_MISSINGS' and 'N' variables.

Suppose you need to keep all the variables from SASHELP.CARS except variables 'MODEL' and 'MAKE'. The DROP= option is used to drop these two variables. Similarly, we can use KEEP= option to keep specific variables. These DROP= and KEEP= Options are not native SQL language. It only works in SAS.

proc sql; create table saslearning (drop= make model) as select * from sashelp.cars; quit;

You can use DELETE FROM statement to remove records (rows) from a dataset.

proc sql; delete from outdata where momage > 0; quit;

In this case, we are deleting all records having momage greater than 0 from outdata dataset. Log shows '478 rows were deleted from outdata'.

Suppose you need to find out employee IDs having records in the table named 'file1' but not in table 'file2'. In the code below, we are querying multiple tables (datasets).

data file1; input ID age; cards; 1 24 2 34 3 45 4 67 ; run; data file2; input ID age; cards; 1 25 3 46 4 62 ; run; Proc SQL; Select ID from file1 Where ID not in (select ID from file2); Quit;

Find employee IDs whose age is in the average age +/- 10 years.

Proc SQL; Select id from file1 where age between (select Avg(age) from file1) - 10 and (select avg(age) from file1)+10; Quit;

In this example, the CASE statement is used to evaluate a condition: whether a student has a score below 70 in any test. To solve this, we have written a subquery that selects "Student_ID" from the "Tests" table where the "Score" is less than 70.

proc sql; select Name,Grade,Teacher, Case When Student_ID in (select Student_ID from Tests where Score lt 70) then 'Failed one or more tests' else 'Passed all tests' end as Test_Results from Students; quit;

If the condition is true, the new column "Test_Results" is assigned the value 'Failed one or more tests.' If the condition is false, the value 'Passed all tests' is assigned to the "Test_Results" column. The result of the query will return the student's name, grade, teacher, and their test results.

About Author:

Deepanshu founded ListenData with a simple objective - Make analytics easy to understand and follow. He has over 10 years of experience in data science. During his tenure, he worked with global clients in various domains like Banking, Insurance, Private Equity, Telecom and HR.

While I love having friends who agree, I only learn from those who don't
Let's Get Connected Email LinkedIn

Well Done Deepanshu, I was almost new to SQL.
But Now I can say that atleast I have learnt basic steps and statements for PROC SQL.
Could you be so kind to share codes for joints as well. Reply Delete